*save_checkpoint

*text_image chap_4.png center Chapter Four
*temp wantworship false
*temp nervous false
*temp madpersephone false
*temp wantworship false
*temp awkwardares false
*temp gotpasthim false
*temp closeup false
*temp wanttoscarehim false
*temp morpheusleft false


[i]Many mortal lifespans ago….[/i]

You ought to get out of the bath. The water has long gone cold and your mother's patience is wearing thin.  

Instead, you sink further below the surface and close your eyes. Darkness cradles you as you drift, weightless and at ease. 

Is this how souls feel after they drink from the Lethe, before sweet oblivion takes hold?

*page_break

A hand brushes your shoulder. Gentle but firm.

*page_break Emerge

"${name}!" your mother gasps. "I thought you had drowned."

You snort under your breath. It would take a lot more than a tubful of water to drown a goddess. Your mother knows this, of course. But she's been all out of sorts on the run up to your first outing as a member of the newly appointed Messengers' Council. 

Now that said outing is upon you, you fear what will become of you under her anxious ministrations.

"You must make haste. Nightfall draws near," she adds, laying your robe out for you and scurrying off before you can respond.

Sighing, you climb out of the tub and dry yourself off. As unbearable as your mother has been, her apprehension is understandable. Today, you will take control of the nightmares that unleashed upon the mortal world when you were born. Today, you will finally embrace your fate. 

You feel….

*fake_choice
    #Ready. I shall do both the gods and the people justice.
        *set leadership %+5
    #Pumped. I can't wait to stretch @{(flightstyle) my wings|my shadows|my legs}.
        *set fitness %+5 
    #Sorrow. A lot of mortals are suffering because of me.
        *set ruthless %-5
        *set nervous true
    #Nervous. I want to make my parents and the Underworld proud.
        *set parents %+5
        *set dutiful %+5
        *set nervous true

You feel your Epiali stir within their shadow dwelling. They've never been let loose in Hellas before. 

Though, you suppose, neither have you.

Sure, you've been to the mortal realm on diplomatic visits and family holidays. But the odd visit to your parents' patron cities or the summers you spent with your grandmother in Eleusis are hardly the same as nightly runs to secure worship and deliver the gods' messages.

@{(nervous) Dread takes hold of you|Anticipation jolts through you} at the thought. No matter what happens tonight–or how you feel about it–life as you know it will change.

*page_break As Will You

Truth be told, things feel different already. [i]You[/i] feel different, and so do your surroundings. There's a strange quality to the air, an urgency to the way time has been shifting. Or perhaps you've simply become more aware of its passing, now that you must keep it. 

The fact that your chambers are unusually quiet only adds to the alienness. The buzz of souls flitting about the balcony and the swoosh of your mother's skirts brushing the floor are the only dents in the swathe of silence.

As soon as she spots you, the Queen stops her pacing and sits you down in front of the mirror. She begins @{(hair) combing|oiling|braiding|adjusting your scarf over} your hair. She insisted on tending to your appearance herself, and does so with deft, knowing fingers. When she's done, she regards your reflection carefully. Your features still bear a shadow of girlhood, but it's waning fast. You'll stop ageing soon, you can feel it. 

Will you stop growing, too?

"Beautiful," your mother says, eyes glistening.

*page_break 

You place your fingers over hers. She nods, gently patting your knuckles. You stay like that for a moment, hands laced, eyes locked.

Then she snaps back into action, hurrying you into your gown and barking conflicting instructions at you before she drags you to the door. 

"Don't forget to be kind." 

"Be firm, be decisive." 

"Do as Hermes tells you, always."

You hear voices floating up from the great hall. A crowd has gathered to witness your departure. Denizens of the Underworld, curious to see if its Lord's daughter measures up.

This is your chance to send them a message, to show them the type of goddess you plan to be.

What do you do?

*choice
    #Grit my teeth and step out before my mother; a show of strength will shut them up alright.
        You lead the way, @{(nervous) ignoring the pounding of your heart against your ribcage|boldly marching down the hall}.

        *if charm < 50
            *set underworldinfluence %+10
            *set maverickgoddess %+10
            You summon your @{(weapon) bident|bow|scythe|sling|staff} for good measure. Its familiar weight fills you with confidence as you lead the way.

            The great hall grows quiet when you make your entrance, chin lifted, gaze hard. The gathered nymphs, satyrs and deities seem to hold a collective breath as they watch you stride by, weapon in hand. Some even take a step back, as if they don't want to take the chance of being caught in your path.
            
            A smart move on their part.
            *goto officialexit
        *else
            *set underworldinfluence %-10
            *set maverickgoddess %-10
            Unfortunately, whatever gossip is currently spreading through the gathered nymphs, satyrs and deities is far more compelling than your entrance. They barely lower their voices, casting sidelong glances at you as you stroll by. There's a few nods of recognition, a couple of pity smiles. 
            
            They don't seem to consider you worthy of much attention, let alone a threat. Perhaps conjuring your @{(weapon) bident|bow|scythe|sling|staff} would've struck some fear into their hearts, you think belatedly.
            
            You scurry towards your family, shame burning your cheeks.
            *goto officialexit
    #Skip the parade and head out through the balcony instead; I hate all this pomp and circumstance.
        *if dutiful < 45
            *set maverickgoddess %+20
            *set parents %-10
            As soon as your mother turns her back on you, you slip out, welcoming the warm breeze on your cheeks. You don't wish to disappoint her, but you're a grown goddess now. Capable of making your own decisions–and your own mistakes.

            Not that this is a mistake. That much is clear when you fly over the great hall, keeping to the shadows so you're not spotted by the knots of deities, nymphs and satyrs gathered there. Waiting for you to make an entrance like mortals at the amphitheatre. 
            
            But you're not some spectacle to be gawked at by overeager fools. You're a goddess, one who doesn't care for putting on a show.
            
            Let them gossip about your absence. Let them figure out you won't bend to their rules; you make your own.

            You glance at your father standing by the exit, straight-backed and deaf to the chatter echoing around him. Zagreus slouches by his side, so lanky and sullen it's hard to believe his talent with a bow already surpasses that of the great archer Apollo's. His gaze flickers toward the rooftop, as though he can sense you lurking in the dark. 
            
            Despite the curtain of hair falling over his face, you spot the grin twitching at the edge of his lips.

            Smart kid, you think as you melt into the night. Hermes is meant to see you off at the gate; best not be late on your first day.
            *goto main13
        *else
            *set maverickgoddess %-10
            *set underworldinfluence %-10
            *set parents %-20
            *set madpersephone true
            Your mother turns her back on you. You @{(flightstyle) unfurl your wings|unfurl your shadows|dig in your heels}, gearing up to slip off the balcony's edge. 

            "No, you don't," the Queen snaps, fingers closing around your wrist. 

            "Mother," you sigh. 

            "Don't you 'Mother' me." Her voice is as hard as her grip.

            "I'm old enough to make my own decisions and I've decided that this is a waste of time."

            "Well, I'm much older than you are, and I've decided that I don't care what you decide. Move. [i]Now[/i]."

            She drags you all the way to the great hall. You manage to shake her off, but not before the gathered deities, nymphs and satyrs notice. They perk up, sensing an opportunity for gossip. You feel like a chastised child. This was precisely why you wanted to avoid the parade. Make your own rules, not bend to theirs. 

            Alas, you've never been much of a rebel. 
            
            Perhaps it's time to change that.
            *goto officialexit
    #Hold my head up high and follow my mother outside; if I'm to be Queen, I should behave like one.
        The great hall goes quiet as soon as you make your entrance. The nymphs, satyrs and deities gathered around the columns seem to hold a collective breath as you glide by, graceful and proud at your mother's side.
        
        *if leadership > 50
            *set underworldinfluence %+15
            *set pantheonplayer %+10
            *set parents %+10
            Their eyes fix on you, and you meet them without flinching. There are a few nods of appreciation, a couple of encouraging smiles. @{(nervous) Your heart pounds against your ribcage, but you don't let it show in your face|It comes naturally, easy}. You feel as though the Fates themselves are guiding your steps, bestowing upon you the poise of a ruler.

            You have successfully commanded their attention, and in doing so laid the ground to earn their respect.
            *goto officialexit
        *else
            *set underworldinfluence %-10
            *set pantheonplayer %-10
            *set parents %-10
            Despite your efforts to command their attention and use this opportunity to garner their respect, it is her they look at. Her they're enthralled by. Their Queen, beautiful as the first blossom of spring. Even the vines twisting around the great hall seem to curl towards her, eager for her to notice them.

            Perhaps one day you'll have a similar effect on those around you, but that day has yet to come.
            *goto officialexit

*label officialexit
*page_break

Hades and Zagreus wait by the portico. Your father is straight-backed as ever, bident in hand, his famed helm resting atop his black curls. Your brother slouches beside him, lanky arms crossed, long hair barely disguising his scowl.

Upon reaching them, your father cups your cheek, eyes gleaming.

"Please spare us the 'my little goddess is all grown up' spiel," Zagreus groans.

Hades's jaw tightens. "Must you complain about everything?"

Your brother rolls his eyes. You resist the temptation to ruffle his curls and wink at him instead. He flashes you a half-grin in return. For a moment, you catch a glimpse of the deity he might become. 

Strong, charming and irredeemably mischievous.

"I best make haste," you say. Hermes is meant to see you off at the gate, and you don't want to be late on your first day.

*if madpersephone = true
    Before you launch into the night, however, you glance back at the Queen. Your mother's gaze is pure steel, her lips pressed into a severe line. Regret twists in your gut. 
    
    She won't forget your betrayal any time soon.

    You swallow a sigh and take off, grateful for the cool breeze.
    *goto main13
*else
    Your mother nods, and you can tell she's fighting the urge to fret over your appearance a final time. You give her a reassuring nod and launch into the night, welcoming the cool breeze.
    *goto main13

*label main13
*page_break

You make for the Lethe, @{(nervous) ignoring your turning stomach|eager to get to the gate}. Souls flicker in the hazy sky, asphodel stirs in the rolling fields, and wind carries the distant cries of the damned.

The wood surrounding the river is as familiar to you as the acropolis's onyx halls and Elysium's winding streets. It's where you learned to hunt, where you practice unleashing your Epiali, where you flee when your mother's fretting and your father's sullenness get too much. 

Yet, when you land on the mossy banks, you feel as though you're seeing them for the first time. No longer school or sanctuary, but something new. Something that teeters at the edge of your awareness. A secret about to be told, a path about to unfold.

You're the first one to reach the meeting point. Nestled among white poplar and cypress trees, it's less of a gate and more of an archway. Cyclops-made, and it shows. The ribbed columns are sturdy but delicate-looking. One is made of shiny ivory, the other of dark horn. Cerberus has been carved into the keystone with such detail, you wouldn't be surprised if the three heads started barking.

Beneath them, a black abyss beckons you forth. You behold it with….

*fake_choice
    #Admiration.
        *set dutiful %+5
        @{(nervous) What lies beyond may fill you with dread, but that doesn't mean you can't appreciate such an architectural feat when you see one|It's an architectural feat}.
    #Suspicion.
        *set charm %-5
        @{(nervous) It's strange,|What lies beyond may excite you, but that doesn't mean you have to enjoy the strangeness of} standing on the threshold of another realm.
    #Curiosity.
        *set cunning %+5
        @{(nervous) What lies beyond may fill you with dread, but you can't help but be drawn to the gate|At what lies beyond, at how different it feels to be standing on the threshold of another realm like this}.
    #Caution.
        *set demure %+5
        @{(nervous) It's strange,|What lies beyond may excite you, but that doesn't mean you have to enjoy the strangeness of} standing on the threshold of another realm.

You press your fingers to one of the pillars, examining the craftsmanship more closely. The ivory is cool against your palm, and the abyss flutters, as though welcoming your touch.

Then someone speaks behind you, startling you into dropping your hand.

"Getting the jump on me, Princess?"

*page_break Turn Around

A god you recognize all too well is leaning against the trunk of a cypress.

"Morpheus," you greet him, biting back a sigh.

His wings stir. They're an ashy grey, intricately paned and almost iridescent. A few strands of his gleaming silver hair have come loose from the half-knot barely keeping it in check. They do nothing to soften the sharpness of his features, or the harshness in his violet eyes.

He's like a rough diamond, glinting in the darkness that bore it. Beautiful to look at, despite the jagged edges.

*page_break

It's not just Morpheus's edges that are jagged, though. You doubt he has a nice bone in his tall, lean body.

He's always getting caught in some sort of trouble or other. Sneaking off to Hellas to toy with mortals' dreams unchecked, stealing Hecate's sacred torches and, more recently, unleashing the Minotaur at an Olympian feast.

His despicable behavior has forced your father to meet with his–the sleep god Hypnos–on countless occasions. 

Unlike his son, Hypnos is a mild-mannered and soft-spoken god. It's not hard to see why he's so beloved by the Underworld's nymphs.

Morpheus is the eldest of his many children and, you don't doubt, the worst behaved.

On the handful occasions you've had the displeasure of talking with Morpheus, he's been unpleasant at best, downright cruel at worst. This time is no different.

"Should've guessed Hades's precious daughter would get special treatment," he says, thorns stuffed into every word.

How do you respond to such a rude–and unwarranted–remark?

*choice
    #I put him in his place, which is so far beneath mine I wouldn't usually bother stepping on it.
        "Speak to me like that again, son of Hypnos, and I shall have your tongue removed," you snap.

        *if ruthless > 50
            *set underworldinfluence %+10
            *set morpheuskneeled true    
            The wood grows still around you. As if the Underworld senses its future Queen's wrath. As if the branches might pull Morpheus's tongue out themselves. The shift isn't lost on the god. His smirk falters and the marble of his face cracks enough to show a glimmer of fear.

            "Now," you add, "I believe you owe me a bow."
            
            His gaze hardens. For a moment you think he might refuse. He certainly looks like he wants to. But he obliges, pushing off the cypress and getting down on his knees. The tips of his folded wings brush the forest floor as he glares up at you.

            "Satisfied?" He seethes, lifting his chin.

            The sight of him kneeling before you but still defiant makes you feel
            
            *choice
                #Rage. Keen, searing desir–I mean, rage.
                    *set Morpheus %+15
                    *goto main14
                #Determination. I will bring him to heel.
                    *set Morpheus %-5
                    *goto main14
                #Indifference. He's kneeling, that's all that matters.
                    *set Morpheus %-15
                    *goto main14
        *else
            *set underworldinfluence %-10
            A mocking grin cracks the marble of his cheekbones.

            "My tongue is highly valued among the nymphs and satyrs in your service." He splays his wings slightly, amethyst eyes flashing. "Remove it, and you might have a riot on your hands."

            You swear you can hear the souls above giggle. Not only have you embarrassed yourself, but you have further emboldened him. 
            
            Rage burns through you, so hot you're certain it will melt the moss beneath your sandals. 
            
            It only makes his smirk wider.
            *goto main14
    #I blush, unused to being called out so and, I must admit, rather tongue-tied by his dashing looks.
        "I…" You stammer, searching for the right words and coming up short.

        *if demure > 45
            *set Morpheus %+10
            *set pantheonplayer %+5
            His smirk falters and the marble of his face cracks enough to show a glimmer of regret. He pushes off the cypress and lifts his hands apologetically. 
            
            He doesn't say sorry, though.

            "That was uncalled for," he admits instead, gaze softening slightly. Then he flashes you a grin and adds, "I swear I won't bite. Unless you want me to."

            Your cheeks burn so hot you're afraid they might melt.
            *goto main14
        *else
            *set Morpheus %-10
            *set pantheonplayer %-5
            His face hardens to marble, his amethyst glare going cold as Tartarus's depths.

            "Do not play the fool with me, Princess," he snarls. "The only thing worse than an entitled deity is an entitled deity who pretends they're not."

            He crosses his arms before his chest, wings flickering like black flames. Disdain oozes from him as you scramble for a response. 
            
            But your throat remains closed as a fist.
            *goto main14
    #I play nice, using my wiles–feminine and otherwise–to distract him from his pathetic little tantrum.
        "Special treatment? Why, I assure you it's nothing like that. I was merely admiring the craftsmanship." You make your voice tremble slightly, feigning dismay. "And, I must admit, rather panicking about what lies ahead."

        You bite your lip and look up at him through your lashes.
        *if cunning > 45
            *set maverickgoddess %+10
            The marble of his face cracks enough to show a glimmer of doubt.

            "Forgive me," he says, though he doesn't sound particularly sorry. "I can see how the prospect of work would be daunting for a goddess of your position."

            There's mockery in his voice, sure, but there's something else too. A challenge. It makes you

            *choice
                #Smile. The only thing better than a battle of wits is a battle of wits with a handsome opponent.
                    *set Morpheus %+10
                    *goto main14
                    *set Morpheus %+5
                #Sigh. As much as I love a battle of wits, I would prefer a different, better-looking opponent.
                    *set Morpheus %-10
                    *goto main14
                #Snort. I'm not interested in a battle of wits, no matter how handsome the opponent.
                    *set Morpheus %+5
                    *goto main14
        *else
            *set maverickgoddess %-10
            The marble of his face doesn't crack, however, and his eyes harden. As if he can see right through your act. As if he doesn't appreciate being played for a fool.

            "It's called work, Princess," he snarls. "You will become familiar with the concept soon enough."

            His wings flicker around him as he sulks. You bite back a sigh. So much for distracting him.
            *goto main14
    #I ignore the jab and focus on de-escalation, assuring him that there's no funny business going on here.
        "I can see how it might seem that way," you acknowledge, stepping away from the gate and smiling politely. "But I can assure you my father's position will have no bearing on my performance tonight."
        
        *if diplomacy > 45
            *set pantheonplayer %+5
            He eyes you carefully, wings fluttering behind him.
            
            "Is that so?"

            "Truly." Your smile widens, and you nod back at the gate, its gleaming pillars, its glaring three-headed dog. "I was merely admiring the stonework. Beautiful, isn't it?"

            The marble of his face cracks enough to show a glimmer of curiosity. "I suppose."

            Good, you think, even if his arrogant smirk remains firmly in place. Curiosity is better than outright animosity. Curiosity gives you something to work with. 
            
            And one thing you're certain of is that Morpheus is a piece of work indeed.
            *goto main14
        *else
            *set pantheonplayer %-10
            "Spoken like a true diplomat." The last word is almost a snarl. "Am I to believe you were merely admiring the stonework, then?"

            "I–"
            
            His amethyst gaze flashes, and that cruel smirk cracks the marble of his cheeks.

            "No, Princess. You may be used to everyone fawning over you, but I won't fall for your lies, no matter how convincingly you tell them." 
            
            He crosses his arms before his chest and glares at you with such intensity you almost take a step back.

            So much for de-escalation.
            *goto main14
        
*label main14
*page_break

You are interrupted by the flap of wings above. You look up to find two figures cutting through the shadowy sky. 

Hermes is easy to recognize. Feathered wings unfurl from his sandals and his helm like fins, and he's holding his short staff before him like a torch. His companion is a deity you've never seen before, with a mane of flowing honey-colored hair and pearly wings that leave a rainbow trail behind them.

@{(morpheuskneeled) Morpheus gets to his feet, brushing the dirt from his chiton before they land|They land by the gate, graceful as birds}. Even in the Underworld's dark depths, Olympus clings to them. A golden hue haloes their skin and their tunics are a white so pristine it glows. Even their matching satchels, full of scrolls to be delivered once your induction is over, are immaculate.

*page_break

You can't help but think how different they look from Zeus's young son–and Hermes's half-brother–Ares. When your old friend's clothes weren't smeared from training or riding or hunting, they were streaked with flour and syrup from raiding the kitchens and crawling beneath feasting tables.

The last time you saw him, he must've been Zagreus's age. He had just returned from slaying a giant serpent who had been terrorizing a mortal village.

Zeus had made him join the feast so that he may regale his guests with tales of the battle. He had a slight limp and was drenched in ichor. Not all of it belonged to the serpent. Some of his wounds had yet to close, they were so severe. He looked every bit the warrior god he had been born to be. Until his hazel eyes had found yours. 

He'd smiled then, and he was a boy once more. A boy

*fake_choice
    #I think about rather often, I must admit.
        *set Ares %+10
    #I feel for; he deserves better than Zeus.
        *set dutiful %-5
        *set ruthless %-5
    #I would love to test my strength against.
        *set fitness %+5
    #I should keep tabs on, for he could be a powerful ally.
        *set cunning %+5
    #That doesn't make me smile in the same way.
        *set Ares %-15

*page_break

Hermes clears his throat, bringing your attention back to the wood. He's a wiry god, with a shaggy mop of brown hair peeking beneath his hat, and eyes the grey of slate. He adjusts the strap of his satchel, making the scrolls peeking out of it clink together, and aims his staff at his companion.

"Greetings, fellow heralds." He has a funny way of speaking. Hurried to the point of dismissiveness. "This is my aide, Iris. They will be running errands for me while I run errands for the gods."

Iris bows. Morpheus returns the gesture. Who knew he was capable of manners?

"Pleased to meet you, Iris," he says. "Tell me, is that Stygian water at your hip?"

You follow his gaze to the waterskin dangling from Iris's girdle.

"It is indeed. Should you wish to swear a Stygian oath, summon me forth and I shall bound you to your word." Iris's eyes change from pale green to steel grey when they speak. 

You study them anew. To bear witness to deities' unbreakable vows is a great honor. Despite their youth, they must be well-respected amongst the pantheon to have earned it.

"Yes, yes, and they've been sworn to secrecy, so they can't discuss your oaths unless you break them," Hermes adds, looking at Morpheus in a way that strikes you as rather odd. Pointed.

There's no time to dwell on it, however, as the herald continues, "Now that introductions are out of the way, let us move on. And swiftly, for there's much work to be done yet."

He snaps his fingers and two scrolls disappear from his satchel. One re-appears before you, the other before Morpheus. 

*page_break

You scan the words scrawled across the parchment and feel @{(nervous) like you might choke on your nerves|a rush of anticipation}.

"There's nothing in there you don't already know," Hermes declares before you have a chance to finish reading. "Send out your daemons, deliver your messages, everyone must worship, yada, yada, yada. Any questions?"

His gaze leaps to the sky, as though his mind has already taken off even if his body remains put. 

As 'put' as relentless foot-tapping, finger-drumming and strap-adjusting can be, that is.

"No questions. But I do have a proposition. A challenge, if you will."

At Morpheus's words, Hermes ceases fidgeting. 

"Go on."

"I have no doubt Hades's daughter here will unleash terrible dread upon mortals," Morpheus says. He wears many rings and many earrings, and they all blink and flash when he moves closer to you. "But can she do so faster than I can spread joy, I wonder?"

"First night on the job and already taunting your fellow messengers. You're certainly living up to your reputation, son of Hypnos." Hermes sounds keen–and delighted. "What do you say, aide, should we let these two have a little fun?"

Iris frowns. "Mortals deserve better than being treated like pawns in a game, my Lord."

"Do they now?" A smirk dangles at the edge of Hermes's lips. It's obvious he doesn't agree. "And what about our lovely Mistress of Nightmares? What does [i]she[/i] think of this daring provocation?"

*choice
    #Morpheus will regret thinking he stood a chance against me. "Bring it on."
        *if ruthless > 45
            *set Morpheus %+10
            *set maverickgoddess %+10
            He glares right back.

            "Iris, is it me or has the temperature in this perpetually damp and cold realm actually risen?"
            
            "Perhaps there has been an eruption by the Phlegethon," you offer, tearing your eyes away from Morpheus and smoothing the non-existent creases in your gown.

            "Yes, it's a pernicious river that one," Morpheus agrees, crossing his arms.
            *goto main15
        *else
            *set respect %-10
            *set Morpheus %-5
            *set underworldinfluence %-10
            He doesn't bother looking at you, making a big show of examining one of his fingernails instead. As if he isn't the least bit threatened. 
            
            Is this how the realm thinks of you? All bark, no bite? You try to disguise how much the thought disgusts you by smoothing the non-existent creases in your gown. 

            "That's the spirit," Hermes says. You pretend it doesn't sting when he adds, "alas, my coin is on Hypnos's son. Iris, care to weigh in?"

            Iris spares you further embarrassment by shaking their head. "I'd prefer not to."
            *goto main15
    #I wink at Hermes, eager to win him over. "I don't mind a little provocation."
        *if charm > 45
            *set respect %+15
            *set pantheonplayer %+10
            "A goddess after my own heart," he says, shooting you a conspiratorial grin.

            You laugh demurely. "Does that mean you'll bet on my victory?"
            
            Morpheus stiffens beside you. The message in the glance you toss him is clear. [i]Getting cold feet?[/i]

            He refuses to meet your gaze. Oh, the satisfaction it brings you.

            "It does indeed, daughter of Hades," Hermes confirms.

            Your raise your eyebrows at his aide. "What about you, Iris? Care to place a bet?"

            Their lips twitch upwards. It's not a smile, but it's not not one either.

            "I do not gamble," they say, eyes turning a light, clear amber. "But I wish you both good fortune."
            *goto main15
        *else
            *set Morpheus %-10
            *set respect %-5
            Iris's eyes darken, Morpheus smirks.

            But Hermes seems in good spirits. 
            
            "A goddess after my own heart," he beams.

            "Does that mean you'll bet your coin on my victory?" You chance. After all, you don't get if you don't ask.

            "A goddess after my own heart indeed," he laughs, though he doesn't answer your question.

            "Sucking up to the boss, Princess?" Morpheus whispers, low enough that only you can hear him. "How desperate."

            You grit your teeth against the coldness in his voice, the shard of shame it brings.
            *goto main15
    #I believe mortals must be protected, even if it makes Hermes mad. "Iris is right."
        "We owe mortals more than that," you add. "So much more."

        *if dutiful < 50
            *set respect %+10
            *set peoplepleaser %+10            
            Iris casts you a grateful nod. Their eyes change once more, turning a warm amber hue.

            "Ah. And yet, we toy with them regardless," Hermes says. The lightness in his voice clashes with the sharpness in his gaze. "After all, eternity would be so dull without a little mischief."

            What a callous, and rather cowardly, statement. Morpheus intervenes before you can argue against it.

            "If you don't believe yourself capable, Princess, just say so. No need to be a martyr about it."

            He makes it all too easy to imagine @{(weapon) skewering his puffed-up chest with your bident|putting a few arrows in his puffed-up chest|beheading him with a clean sweep of your scythe|strangling him with your sling|giving him a few good whacks with your staff}.
            *goto main15
        *else
            *set respect %-20
            *set olympusinfluence %-10            
            There's a weight to your voice, a sharpness to the words. You're not used to going against what is expected of you, and it shows. 
            
            Silence presses down on the clearing. Hermes's eyes narrow and Morpheus frowns. Even Iris looks concerned, despite the fact that you were agreeing with them. Perhaps you shouldn't have done so quite so loudly, and with such intensity.

            "Being a martyr is so very boring," Hermes says. His tone is light, his demeanor easy. They don't hide the sharpness that has infiltrated his gaze, the sudden stiffness in his shoulders. "Besides, there are far more creative–and effective–ways to secure a bit of extra worship for yourself than grovelling and pandering."

            "I…ah…that's not…," you stammer, feeling foolish.
            
            The trees seem to close in on you, the souls are too bright. 
            
            You wish you had your mother's command of nature so that you could make the earth swallow you whole.
            *goto main15
    #I flex my muscles, eager to prove my physical prowess. "She's ready to win."
        *if fitness > 50
            *set respect %+10
            *set Morpheus %+5
            *set maverickgoddess %+10        
            Hermes gives you an approving nod before turning to Morpheus. "As much as I admire your bravado, son of Hypnos, my coin is on Hades's daughter. Iris, care to wager?"
            
            "I'm afraid I'm not a betting deity, my Lord," the aide says, smiling lightly. "Though if I were, I would toss my coin alongside yours."

            Their vote of confidence fills you with satisfaction. And, you must admit, more than a little smugness. You let it show when you smile at Morpheus, who regards you with what could, if you squint, be interpreted as a smidge of respect.
            
            "Unfavorable odds will make my victory even sweeter," he declares, tossing back his white hair.
            
            Your smile only widens.
            *goto main15
        *else   
            *set respect %-10
            *set maverickgoddess %-10
            *set Morpheus %-5
            Hermes eyes you with more than a smidge of skepticism. 
            
            "That's the spirit," he offers weakly.

            It's the kind of encouragement a grown-up might give a child when they don't want to hurt their feelings. Oh, how it stings.

            "I was trained by Chiron himself," you add, hoping the centaur's name will reassure Hermes of your strength. "Beating some overeager attention-seeker will be a breeze." 

            But Hermes has stopped listening.

            Morpheus leans in close enough that you can feel his breath when he whispers, so low that only you can hear him, "Resorting to name-dropping, Princess? How desperate."

            He makes it all too easy to imagine @{(weapon) skewering his puffed-up chest with your bident|putting a few arrows in his puffed-up chest|beheading him with a clean sweep of your scythe|strangling him with your sling|giving him a few good whacks with your staff}.
            *goto main15
    #I give Iris a reassuring nod. "A contest could certainly make things interesting."
        *if diplomacy > 40
            *set pantheonplayer %+5
            *set olympusinfluence %+10
            *set Morpheus %-5
            Iris nods back, their eyes softening to green once more.

            "Hedging your bets, I see," Hermes says, tossing you a half-smile. "Smart move."

            "Or is it a cowardly one?" Morpheus interjects.

            Hermes raises an eyebrow. "I suppose that's for the Fates to decide."

            "And the fastest messenger," Iris adds, giving you a pointed look.

            You smile, grateful for the vote of confidence.
            *goto main15
        *else
            *set respect %-10
            *set olympusinfluence %-10
            *set Morpheus %-15
            "Certainly," Hermes agrees, though his voice is tinged with disappointment.

            You shouldn't be surprised. He isn't known for favoring diplomacy. Cunning, yes. Mischief, sure. But hedging his bets? Never.

            You look to Iris, hoping your words might have reassured them. But the aide remains aloof, the shade of their eyes an impenetrable black.

            "Pander all you like, Princess," Morpheus whispers in your ear, low enough so only you can hear him, "but you can't swim without getting wet." 

            His voice is ice on your spine.
            *goto main15

*label main15
*page_break

Hermes claps his hands together, and the sound echoes through the wood.

"It is decided, then. We shall have a contest."

Morpheus grins triumphantly. "A wise decision, my Lord." 

You roll your eyes.

"I trust you will find a way to track who returns first," Hermes adds. Both the wings of his hat and the ones at his ankles stir, lifting him a few spans into the air. "Now, if you'll excuse me, I have messages to deliver and souls to escort."

He adjusts the strap of his satchel once more and launches into the sky.

Iris bows at you, then at Morpheus. "Pleasure," they say before they follow after him.

You marvel at the trail they leave behind. It's made of bright lights in a myriad of different colors, some of which mimic the ones you've seen reflected in the aide's eyes.

*page_break

"Well, Princess, I hope you enjoy being humbled," Morpheus says, cracking his knuckles. Then he laughs and shakes his head. "Who am I kidding? I hope you hate every second of it."

You don't bother replying. Instead, you dash for the gate, using your @{(flightstyle) wings|shadows|sandals} to propel you forward. 

The last thing you hear before the black abyss swallows you whole is Morpheus's strangled gasp.

*page_break What A Sweet Sound

[i]Present mortal lifespan….[/i]

Everything might've changed after you stepped through the gate that first time all those centuries ago, but Council meetings remain more or less the same.

Hermes still speeds through the agenda. Morpheus still goes out of his way to taunt you. Iris still does their best to keep everyone on the right track, with varying degrees of success.

And you're often caught between them, a fear pushing through the Halfrealm's depths. 

*page_break

On the morning of the full moon, before you're meant to convene, you @{(hobby) set up your loom in the courtyard, joining the nymphs weaving and gossiping beneath the souls|are challenged to a race by some nymphs|bring your aulos to the courtyard|are challenged to a game of kottabos by some of the nymphs gathered in the courtyard}.

@{(hobby) Cups of nectar are passed around, and you work the thread with deft fingers|Beating them isn't easy, and Averna comes close to overtaking you|The nymphs gathered there are delighted to have an accompaniment to their weaving|You happily join them on the recliners they've arranged around the pole, already fitted with a bronze disk}.

*if hobby = 1
    Averna leans over and whistles.
    *goto tapestry
*elseif hobby = 2
    Ultimately, however, it's you who crosses the finish line first.
    *goto breakthoughts
*elseif hobby = 3
    Averna brings out a lute, and begins singing rude songs that draw giggles from the others.
    *goto breakthoughts
*else
    You take turns flinging nectar at it, attempting to dislodge it so that it may fall and hit the metal plate at the foot of the pole.

    Averna wins the first round. You win the next before she beats you anew.

    On and on you go.
    *goto breakthoughts

*label tapestry

What does your tapestry depict?

*fake_choice
    #A great battle, brutal and bloody.
        *set ruthless %+5 
        *set tapestry 1
        Warriors wielding weapons and shields, spears piercing the air and their flesh, blood coating their hands and the marble beneath their sandals.

        A scene that is raw and real, and which might cause anyone admiring it to turn away in horror. 

        But not you. 

        You like to face horror head on.
    #Your family, resplendent and regal.
        *set parents %+5
        *set Zagreus %+5
        *set tapestry 2
        Your parents sitting on their thrones, Zagreus wielding his bow, and you, half shrouded in shadow, a pair of ghostly @{(epiali) snakes curled up at your feet|bats perched on your shoulder|crows perched on your shoulder|cats curled at your feet|spiders crawling up your arm}.

        Half portrait, half scene.

        One @{(parentsrel) you know they'll|they better|you hope they'll} be proud of, when you show them.
    #A feast, majestic and mirthful.
        *set charm %+5
        *set tapestry 3
        Music, wine, food and nectar.

        Nymphs, satyrs, deities and mortals.

        A scene that will delight anyone who beholds it.
            
@{(tapestry) As does Averna, it would seem.|"Beautiful," Averna says, squeezing your shoulder. Then she winks. "Though I doubt Zagreus has ever covered that much skin."|Including Averna, it would seem.}

*label breakthoughts
*page_break

@{(hobby) The others laugh|You all retire to the baths, where you share cups of nectar and gossip|A small crowd gathers, and the seeds of a great feast are planted|Chatter, laughter and nectar fill the gaps between turns}.

Demands for stories of the Halfrealm are made, and you gladly oblige them.

"Poor things, to have their dreams ripped away so," sighs wistful-eyed Eurydice.

"And their fears turned against them," adds pale-skinned Leuce.

"Fear sharpens the mind," tuts Averna, tossing you a wink.

They begin debating the merits of fear, or lack thereof.

*page_break 

Instead of joining them, you @{(hobby) focus on the tapestry|sip on your nectar and enjoy your soak|sit back and enjoy a cup of nectar|sit back and enjoy a cup of nectar}.

Soon, your mind is wandering. The meeting looms, as does your future and, if the Giants attack, that of the realms.

It dawns on you, then. 

You are on the brink of a seismic change, just like you were on the run up to that very first nightmare run.

But this time, there is even more at stake. Your fate. 

Your heart.

Breath snags in your throat at the thought, and the memory that pops into your mind without warning alongside it.

Of your recent

*choice
    #Outing to the Eastern border, where I saw Ares.
        *set Ares %+5
        *set thoughtof 1
        @{(unsureaboutares) When it comes to your future, your mind is far from made up, but seeing|Seeing} him again after all this time brought back so many memories.

        And it made you wonder about building new ones. @{(marriage) Could you secure the alliance between your realms, and live|Could you have power beyond your wildest imagination and live|Could you have the love you've always dreamed of and live|Could you reject the politics of marriage and live} a happy life by his side?

        You don't know the answer. But perhaps you were searching for it when you swung by Hellas's Eastern border before delivering a nightmare nearby.
        *goto aresmini
    #Argument with Morpheus on the banks of the Lethe.
        *set thoughtof 2
        Eternity hasn't dulled the edge of his spite. If anything, it has sharpened it.

        Being in his presence feels like having a knife at your throat. And whenever his cruel, unflinching eyes meet yours, the steel presses in closer.

        He had sought you out, after
        *if race = 8
            he tricked you into victory.

            As though he couldn't wait to gloat.

            The arrogant brute.
            *goto morpheusmini
        *if race = 7
            you tricked him into victory.

            As though he couldn't wait to gloat. 
            
            Just as you predicted.
            *goto morpheusmini
        *elseif race = 5
            you left him to his little race. 
            *goto morpheusmini
        *elseif (race = 1) or (race = 3)
            you beat him back.
            *goto morpheusmini
        *else
            he beat you back. 

            As though he couldn't wait to gloat.

            The arrogant brute.
            *goto morpheusmini        
    #Foray into the Halfrealm, and Theron's nightmares.
        *set Theron %+5
        *set thoughtof 3
        Hermes hadn't sent you to torment him again but, each time you enter the Halfrealm, you invariably find yourself in one of his dreams. 

        Drawn to him by its shadowy currents, and your own wayward thoughts. 

        Wayward thoughts that mirror his own, it would seem.

        For, most nights, he dreams of you.
        *goto theronmini

*label aresmini
*page_break

The sun was low in the horizon, but not yet vanquished by night.

Tufts of smoke rose between the tents on either side of the battlefield, where only the ruined spears and shields of the fallen remained.

The dead had already been taken care of, and the living had retired for the day.

*page_break

Ares had been easy to spot. He towered over a giant cast iron pot, ladling its steaming contents into bowls and handing them out to the throng of hungry warriors surrounding it.

He wore no armor. Only his red tunic and an apron tied over it.

Now that's a sight you've never come upon before. A [i]god[/i], serving [i]mortals[/i]. Not through some overwrought display of might to earn worship; but through labor.

Through kindness.

@{(ruthless > 45) It had felt so alien|It had warmed your heart}, to witness it.

He was so focused on his pot, he didn't notice you approach, or hear the curious whispers uttered by the gathered soldiers in your wake.

What had been your greeting again?

*fake_choice
    #"Nice apron."
    #"What's cooking?"
    #"Fancy seeing you here."
    #"Is this another of Maia's recipes?"

He had almost lost the ladle to the depths of the pot.

Still, you remember with precise clarity how wide his hazel eyes had gone, how surprised his voice had sounded when he rasped your name.

And how pleased he had seemed, once the surprise had ebbed.

"War god got himself a lady goddess," one of the soldiers teased.

"About time," another hollered.

Ares had narrowed his gaze at them. Then he'd done the most surprising thing a god who had just been ridiculed by a mortal could do. 

Nothing. 

Nothing but wave them off, that is.

*page_break

"Are you here for a delivery?" He'd asked, a half-filled bowl in one hand, the ladle in the other.

"Something like that."

"C'mon war god, we're hungry," a woman with a bandage around her middle grumbled. 

"I'm coming, I'm coming," Ares sighed, casting you an apologetic smile before returning to his serving. "Damn mortals. You lot always need something, don't you?"

But there was no malice in his voice, only comradery. The kind his parents discouraged, when it came to mortals. And yet, he appeared completely at ease with it. Completely at ease with himself. 

In some ramshackle camp, serving stew to bruised and bloodied warriors.

You had helped him, of course.

*choice
    #It was the right thing to do, even if it wasn't proper.
        *if dutiful < 50
            *set Ares %+5
            *set peoplepleaser %+10
            *set worship %+5
            *set camp 1
            *goto aresmini2
        *else
            *set Ares %-5
            *set peoplepleaser %-15
            *set camp 2
            *goto aresmini2
    #It was the kind thing to do, even if it wasn't proper.
        *if ruthless < 50
            *set Ares %+10
            *set peoplepleaser %+5
            *set worship %+5
            *set camp 3
            *goto aresmini2
        *else
            *set Ares %-10
            *set peoplepleaser %-10
            *set camp 4
            *goto aresmini2
    #It seemed like a surefire way to secure their worship.
        *if cunning > 60
            *set worship %+10
            *set peoplepleaser %+5
            *set Ares %-5
            *set camp 5
            *set wantworship true
            *set skimmedworship true
            *goto aresmini2
        *else
            *set Ares %-5
            *set worship %-5
            *set camp 6
            *goto aresmini2
    #It seemed like a surefire way to secure Ares's attention.
        *if demure < 45
            *set Ares %+10
            *set peoplepleaser %+10
            *set camp 7
            *goto aresmini2
        *else
            *set peoplepleaser %+5
            *set pantheonplayer %-10
            *set camp 8
            *goto aresmini2

*label aresmini2

You nodded at the apron, then at the ladle. "Got more of those?"

Again, he had paused. And again, the soldiers had teased him for it. He disappeared into a tent and returned with another apron and ladle. You took them off him and got stuck in.

And, as you served the tired warriors, who teased Ares, who laughed and joked and wondered at your presence,
*if (camp = 1) or (camp = 3)
    you had felt it. 

    A sense of purpose, of warmth. 

    Of comradery.

    From them, and from Ares, who kept stealing glances at you every chance he got.
    *goto aresmini3
*elseif camp = 2
    you had felt it. 
    
    The impropriety of it all. Chafing at you, making you stiff and sour-faced.
    *goto badtime
*elseif camp = 4
    *set awkwardares true
    you had felt it. The urge to glare at them, to strike fear in their hearts and rip the mockery form their tongues.

    And it showed.
    *goto badtime
*elseif camp = 5
    *set awkwardares true
    you had felt it. 

    Their reverence, growing with each kind word, each honeyed smile you chucked their way.
    
    But Ares's wariness grew alongisde it, as though he knew why you were really doing it. 
    *goto badtime
*elseif camp = 6
    you had done your very best to charm them. Kind words, pretty smiles, soft jokes.

    But it was Ares alone, with his lovely dimples and his easy way, who earned their reverence, and he alone who would receive their worship.

    You had no choice but to swallow your disappointment and soldier on.
    *goto aresmini3
*elseif camp = 7
    you had felt it.

    His gaze on you, warmer than the sun had been on the flight here.

    He couldn't tear it away, no matter how clumsy it made him, or how much mockery it earned him.

    You savored every second.
    *goto aresmini3
*else
    you stole glances at him every chance you got.

    But he was too devoted to his task, to his fellow warriors, to return them.

    And you felt too awkward and out of your element to do anything else but let him.
    *goto aresmini3

*label badtime

@{(wantworship) As though he didn't approve|Wary glances were hurled your way, and hurried grumbles replaced the laughter that had abounded around you before}.

@{(wantworship) "They've given enough today,"|"You don't have to do this, you know,"} Ares had murmured between serves. The line of his shoulders was tight, and his dimples were nowhere to be found.

@{(wantworship) You aimed an affected glance at him. "So they have."|"Nonsense."} 

@{(wantworship) He nodded, but you're not certain he was convinced|You had meant to reassure him, but neither of you were convinced}. 

*label aresmini3
*page_break

By the time everyone was fed and the mess cleaned up, the sun had long disappeared. 

Glowing stars and dying embers lit the camp, and most soldiers were already abed.  

"I had better leave, I'm running late," you'd told Ares.

"Thanks for swinging by," he said. Then his gaze had found yours and his cheeks flushed. "Out of curioisty, why did you? Swing by, I mean."

What did you reply?

*fake_choice
    #"I wanted to see you again."
        *set Ares %+5
        He grew as red as his tunic. @{(demure > 45) As did you|Your smile only grew wider}.

        "It pleases me to hear it."
    *if wentwithares
        #"I wanted an update on the drakon hatch."
            *set daemonhandling %+5
            His face had softened.

            "Iris is keeping an eye on them. They haven't hatched yet. I'm hoping to make it back before then."

            You nodded, and hoped for the chance to witness it.
    *if (aresmarriagetalk = true) and (unsureaboutares = false)
        #"To honor the deal we made in the grove."
            *set Ares %+10
            He grinned. 

            "It pleases me to hear it."
    #"Delivery nearby."
        *set diplomacy %+5
        He gave you a small smile.
    #"Do I need a reason?"
        *set charm %-5
        He shook his head, lips twitching upwards.

Then he toyed with the strap of his apron.

"My family thinks it's unidgnified, all this." He nodded at the pot, empty and sparkling, and the tents, full of the sounds of fitful sleep. "But there's nothing dignified about war."

Feeble-minded and helpless, Zagreus's harpist had called him. But those were Athena's words. Words he's used to, by the sounds of it

He raked a hand through his hair. In the dark, it looked more umber than bronze.

If you had time, you might've stayed. Might've attempted easing the anguish in his @{(indifferentaprhodite) voice|voice. Might've asked him about Aphrodite, and whether there's still something between them}.

But you didn't. These days, it feels like you don't have time for anything, despite possessing an eternity's worth.

"Good night, Ares," you told him, handing back the apron and meeting the sky.
*goto nymphs

*label morpheusmini
*page_break

You were following the Lethe back to the palace, its unwrinkled surface dotted with souls. He'd landed in front of you, blocking your path.

In the sky, above Leukas, he had been too far and you too worked up to dwell on his appearance. 

But it was hard not to, then, in the woods.

Between his imposing height, the moonlit silk of his long hair–woven with braids and beaded with gold–and the constellation of rings glinting in his ears and on his fingers, you doubt your eyes could've focused on anything else.

@{(race) You had crossed your arms and grinned. "Finally caught up, have you? Took you long enough."|"Out of my way, pest," you had snarled|"I should think you would know better than to stand in my way by now," you had snarled|"Out of my way, pest," you had snarled, avoiding his gaze and trying not to think of the feathers you had to pluck out of your hair after your unfortunate collision|"Out of my way, pest," you had snarled|"Out of my way, pest," you had snarled|"Out of my way, pest," you had snarled. Feigning distress at his victory was easy|"Out of my way, pest," you had snarled}.

@{(race) He groaned. "Gloating is unseemly. Unless, of course, I'm the one doing it."|"Such a sore loser," he smirked. "There's no need to be. I won't make you sing my praises as our little contest's indisputable victor. I'm far too humble for that. You can simply list them."|He smirked. "Oh, yes. Seeing you tear through those poor birds sure did struck fear into my heart."|He smirked. "Or what? You'll tear through me like you did those poor birds?"|He smirked. "Ah, it's reassuring to know you're still capable of grit. I was wondering if that had evaporated alongside your ability to have fun."|He smirked. "Or what? You'll humiliate yourself further by pretending you don't care about our little competition until it's too late to do anything about it? Other than lose. Horrifically and humiliatingly so, might I add."|"Such a sore loser," he'd practically purred.|"What? You don't wish to gloat about your hard-earned victory? Oh, that's right. We both know who the real winner is." He had paused for dramatic effect. "Me. The real winner is me."}

You had rolled your eyes and

*choice
    #Pushed past him, glaring so that he wouldn't dare to stop you.
        *if charm < 45
            *set Morpheus %-5
            *set underworldinfluence %+10
            *set gotpasthim true
            It worked. 

            He glided out of your way, throat bobbing, smirk wavering.

            As though he was scared of crossing you. 
            
            As though he was scared of you, period.
            *goto morpheusmini1
        *else
            *set Morpheus %+5
            *set underworldinfluence %-10
            He didn't budge, splayed wings blocking your path.

            His smirk widended, as though daring you to do something about it.

            As though he was looking forward to it. 

            When all you could manage was a groan, he seemed disappointed.
            *goto morpheusmini1
    #Closed the distance between you, eager to catch him off guard.
        *set closeup true
        You stomped forward, stopping only when the tips of your sandals grazed his.

        *if demure < 45
            *set Morpheus %+10
            *set maverickgoddess %+10
            It had worked. 

            His stupid smirk had vanished and, when his eyes had slid down to yours, they were full of uncertainty.
            *goto morpheusmini1
        *else
            *set Morpheus %+5
            *set maverickgoddess %-10
            But it was you who was thrown off by his sudden proximity, not him.

            You who had blushed and averted your gaze when his eyes slid to yours, all your nerve lost to the intensity you found there.
            *goto morpheusmini1
    #Bid him good day, determined not to let him get a raise out of you.
        "Great talk. Bracing as ever. Now, if you'll excuse me."

        You had shot him a polite smile for good measure.

        *if diplomacy > 45
            *set Morpheus %-5
            *set pantheonplayer %+10
            *set gotpasthim true
            He had uttered a disappointed sigh, but he'd glided out of the way.

            It had felt like a miracle, even if you wouldn't be rewarded with worship for it.
            *goto morpheusmini1
        *else
            *set Morpheus %+5
            *set pantheonplayer %-10
            But he didn't budge, splayed wings blocking your path. "I don't think I will."
            *goto morpheusmini1

*label morpheusmini1
*page_break

@{(gotpasthim) "Wait," he'd called out. So low, you wouldn't have heard it if you weren't a goddess.|"Why must you be like this?"} 

@{(closeup) Your sigh got caught in the braids framing|Uncertainty ghosted across} his sculpted face.

It was strange, to see it so devoid of its usual venom.

"I…." 

The word lingered between you. For a moment, you thought he might actually say something serious. 

How very foolish of you.

@{(race) "I just wanted to remind you I'm still the overall winner. If you look at the gate, my side is far fuller than yours."|"I just wanted to gloat. Relish your humiliation while it's still fresh."|"I just wanted to remind you I'm still the overall winner. If you look at the gate, my side is far fuller than yours."|"I just wanted to let you know you forgot a feather." He aimed his gaze at your feet. There, stuck to the sole of your left sandal, was a gull feather. You ripped it off with a grunt as he added, "I thought it would spare you further embarrassment when you reached the palace."|"I just wanted to gloat. Relish your humiliation while it's still fresh."|"I just wanted to gloat. Relish your humiliation while it's still fresh." |"I just wanted to gloat. Relish your humiliation while it's still fresh."|"I just wanted to gloat. Relish your humiliation while it's still fresh."}

@{(gotpasthim) You clenched your fists|Then he glided out of your way, looking far too pleased with himself}. 

But you wouldn't dignify his comment with a response.

Instead, you had met the sky, and were seething the entire way home

Just thinking of it now awakens your rage anew. You can feel it in the pit of your stomach, the back of your throat, the surface of your skin….
*goto nymphs

*label theronmini
*page_break

A tall, stately, beautiful version of you. 

Sometimes she looms over his balcony like a harbinger of death, others she sits at the worn table with him like she's an old friend.

Sometimes she wrecks his beloved ship, tearing it apart until only splinters remain, others she admires its craftsmanship, nodding at smart details and pretty finishes. 

Sometimes she unleashes shadows upon the Leukan agora and its people, others she dances alongside them until the stones crack beneath their feet.

She always fades when you appear, however. As though he knows the real you is  there.

And, no matter what disguise you don or how quickly you try to swim away, the currents pull you back in.

And every time, he offers you the same warm greeting.

"Hello, Goddess."

And every time, you….

*choice
    #Smile back. I'm not there to scare him, and I don't wish to.
        *if ruthless < 45
            *set Theron %+10
            *set peoplepleaser %+10
            *set worship %+5
            *set dream 1
            *goto nice
        *else
            *set Theron %-5
            *set peoplepleaser %-10
            *set dream 2
            *goto scary
    #Smile back. It might inspire him to throw some extra worship my way.
        *set wantworship true
        *if cunning > 60
            *set worship %+10
            *set Theron %+5
            *set skimmedworship true
            *set dream 3
            *goto nice
        *else
            *set worship %-10
            *set Theron %-5
            *set dream 4
            *goto scary
    #Stare him down. He should fear me, that's what I'm there for.
        *set wanttoscarehim true
        *if charm < 65
            *set Theron %-5
            *set pantheonplayer %+10
            *set dream 5
            *goto scary
        *else
            *set Theron %+5
            *set pantheonplayer %-10
            *set dream 6
            *goto nice
    #Swim faster. I despise being bested by the Halfrealm's currents.
        *if fitness > 65
            *set maverickgoddess %+10
            *set underworldinfluence %+5
            *set olympusinfluence %+5
            *set dream 7
            Luckily, you are far stronger than they are.

            And though they may drag you to Theron's dreams, you're always able to pull yourself out.
            *goto theronmini1
        *else
            *set maverickgoddess %-5
            *set underworldinfluence %-10
            *set olympusinfluence %-10
            *set dream 8
            You strain against them, but whatever draws you to Theron appears to be stronger than you are.

            An embarrassing realization, one you have no doubt will be written in the Halfrealm's currents for the pantheon to see.

            All you can do is hope they won't look.
            *goto theronmini1

*label nice

The Halfrealm flutters around you, fears stirring in its depths. 

@{(wanttoscarehim) But they never emerge from them, no matter how hard you will them to|But you will them to still. To leave him be}.

This is where you are @{(wanttoscarehim) meant to be at your most powerful. And yet, whatever draws you to Theron appears to be stronger than you are|strongest. And it shows}.

No nightmare breaks through the surface that you may weave it. 

*if wantworship
    His smile takes on an awed air, his gaze a reverent depth. 

    And your power grows.
    *goto theronmini1
*else
    There is only you and Theron and the waves.
    *goto theronmini1

*label scary

@{(wanttoscarehim) This is your realm,|But the Halfrealm is} where you are most powerful.

And it stirs in your presence, the fears lurking behind the shadows eager for your touch.

They rise to meet you, @{(wanttoscarehim) and you let them|ignoring your efforts to hamper them down}.

Theron's smile falters, as does his dream, before it becomes a nightmare.

A wedding feast emerges from beneath the waves.

*if (wanttoscarehim = true) or (wantworship = true)
    When you leave him, @{(wantworship) worship is the last thing on his mind|it's at the altar, full of gloom that this might be his fate}.

    @{(wantworship) For there's only room for gloom that this might be his fate|It doesn't stop him from yearning for your presence, though. From finding yourself there, over and over}.
    *goto theronmini1   
*else
    The only way to stop it is to flee.
    *goto theronmini1

*label theronmini1
*page_break

Thoughts of him haunt you even now, away from the Halfrealm.

And they're not just of what transpires when you're in its waters.
        
They're of the lines you glimpsed around his eyes when he smiled on that balcony, of his deft way with a whittling knife, of his courage to stand up to a goddess in the name of his people. 

Even if it might only bring him dread.

*label nymphs
*page_break

The nymphs' tittering yanks you back to the @{(hobby) courtyard|baths|courtyard|courtyard}. Their pointed stares make you aware of the @{(hobby) threads languishing between your fingers, any pretense of weaving long abandoned|nectar you've spilled into the water|nectar you've spilled on the divan|nectar you're clutching, rather than chucking at the disk}.

"Us immortals may not need sleep, but we're not immune to daydreaming," Averna teases. 

"Particularly when it comes to love," Eurydice sighs.

"Which god is responsible for such revery, I wonder? Surely someone dark and mysterious," Leuce ventures.

"Nonsense. It must be Ares. He'll make a fine husband," Eurydice declares.

@{(thoughtof) Eurydice isn't wrong, but you're not about to tell her that. You don't want the whole pantheon finding out.|A better one than Morpheus, that's for certain.|What would her and the others say if they knew it was a mortal who made your mind drift and your pulse beat faster?}

*page_break

"I'm not here to fuel rumors about my love life," you say, ignoring their protestations. "But I will take any you have on the love lives of others."
    
Averna says nothing, watching you with a canny expression. 

Fortunately, the others are more than happy to regale you with tales of the pantheon's dalliances.

*if nightmaresuccess = true
    *goto feelworship
*elseif ((camp = 5) or (dream = 3)) and (nightmaresuccess = false)
    *set skimmedworship true
    *goto feelworship
*else
    *goto main16

*label feelworship
*page_break

Later, when you're @{(hobby) soaking in the tub|back in your rooms|soaking in the tub|soaking in the tub} and the scent of @{(flower) crocus|daffodil|quince|nightshade} @{(hobby) is seeping into your skin|greets you|is seeping int your skin|is seeping into your skin}, it hits you. 

A surge of strength. Deep within you, rising like a wave. 

The telltale sign of mortal worship. 

It always comes after a successful nightmare run. Prayers and offerings that fill the well of your power, so that you may draw from it to perform miracles. It isn't a huge well, mind you.
*if skimmedworship
    But it's growing. Especially when you're going out of your way–and risking your skin–to add to it. 
    *goto main16
*else
    But it's enough.
    *goto main16

*label main16
*page_break

Shortly before nightfall blankets Hellas and the full moon lights your way to the Halfrealm, you meet the messengers in the clearing by the gate.

Hermes hovers above the dewy moss, as if he expects to be back in the air too soon to bother making land. 

Iris doesn't follow his lead, sandals firmly planted on the grass.

Morpheus surprises no one by making a dramatic entrance, beating his wings to whip up a wind that makes his hair ripple around him like a halo.

*if (thoughtof = 1) or (thoughtof = 3)
    Gold beads adorn the braids keeping it from his face, matching the constellation of rings in both his ears and on his fingers. His hair reaches below his shoulder blades, moonlit silk. You have no doubt he spends many hours preening in front of his reflection to make it so, even if he doesn't have to.

    @{(race) He makes a big show of ignoring you, keeping his gaze firmly away from yours–and the flower you so swiftly pinned to the gate this morning. Such a sore loser, you think with a satisfied smirk|"${name}," he greets you with a grin. His gaze goes straight to the fresh poppy he pinned to the gate this morning and his grin widens|You meet his gaze and grin when he flinches, the mere sight of you a reminder of his failure the other night–and your might|You avoid his gaze and try not to think of the feathers you had to pluck out of your hair after your unfortunate collision the other night|He gives you an exaggerated bow and glances at the fresh poppy on his side of the gate, as if to remind you of his victory the other night. You stifle a resigned sigh and turn your attention to the others|He shoots you a smug grin, one that fades when you promptly look away|He grins at you smugly, glancing at the fresh poppy on his side of the gate and looking all too pleased with himself. Just as you predicted the other night. Self-absorbed fool|He shoots you a smug, satisfied grin, and though you're the one with a fresh flower on your side of the gate, you feel far from victorious}.
    *goto premeeting
*else
    You wouldn't be surprised if he'd spent many hours perfecting the move in front of his reflection.
    *goto premeeting

*label premeeting
*page_break

Hermes clears his throat, drawing everyone's attention.

"Evening, heralds. Let's keep it brief, shall we? Morpheus, Zeus wishes to congratulate you on inspiring the hero Odysseus to sail back to his homeland. The eagle was a nice touch."

You're well accquainted with Odysseus's subconscious. A dark and disturbed place even before you were sent to fill it with torment. Still, the disgraced hero refused to heed your warnings–and was severely punished for it. Kept from his island kingdom by mighty storms and lovelorn witches. Forced to drift at sea and beg on land. Tortured with nightmares of his home burned to ash in his absence, his line erased.

Nightmares you wrought.

"His wife and son will be glad to see him returned," Iris says.

Morpheus's voice is thick with disdain. "Will they? He's a blood-thirsty brute who thinks himself clever when, in truth, he is merely cruel. A perfect example of the unending arrogance plaguing mortals. Unending arrogance we shouldn't indulge."

He fixes his glare on Hermes, the implication behind his words obvious. Not only are the Olympians [i]wrong[/i], but they are also [i]weak[/i].

The herald's easy demeanor slips. He stops fidgetting and his youthful face darkens.

How do you respond?

*choice
    #I defend mortals; gods are just as arrogant, if not more.
        You clench your fists and address Morpheus, barely able to contain your rage.

        "You speak of mortals' unending arrogance, but what of us gods? We are far more imperious than mortals could ever be. Perhaps we should focus on curbing our own indulgent tendencies instead of criticizing theirs."

        *if dutiful < 50
            *set peoplepleaser %+15
            *set respect %+5
            *set Morpheus %+10
            *set underworldinfluence %+5
            "Oh, I agree with you," Morpheus says. "On the last part, anyway."
            
            Surprise snuffs out your anger. You've never agreed on anything before. Or, at least, you've never admitted to it aloud.
            
            Then Hermes clasps his hands together, startling the souls above.

            "Well, isn't that nice? The Council's Underworld contingent is on the same page for once," he drawls. "Perhaps this newfound comraderie could be put to better use than what sounds dangerously close to questioning Zeus's judgement and defending mortal hubris."

            You lift your chin, holding the herald's gaze. Beside you, Morpheus does the same.

            Iris clears their throat, but it barely cuts through the tension closing in on the clearing.
            *goto main17
        *else
            *set respect %-10
            *set pantheonplayer %-10
            *set olympusinfluence %-10
            *set Morpheus %-5
            It isn't Morpheus who replies, but Hermes.
            
            "I don't know what's more troubling, Morpheus's questioning of Zeus's judgement or your defence of mortal hubris." The sharpness in his tone cuts through your anger. "Either way, I would advise you both to tread very carefully when making such insinuations. For your own sakes, and the sake of your realm."

            Morpheus lifts his chin, defiant as ever. But Hermes's thinly-veiled threat has rattled you. You've seen what happens to those who incite Zeus's wrath, can hear their cries echoing in the distance. 
            
            You can't advocate for mortals if you're thrown into Tartarus.

            So you nod at Hermes, and are grateful when Iris clears their throat. Paying attention to them makes it easier to ignore the betrayal in Morpheus's eyes.
            *goto main17
    #I call out Morpheus's hypocrisy; he's the most arrogant god I know.
        "Speaking of unending arrogance, don't you collect art with your likeness on it?"

        Your words cut through the tension that had closed in on the clearing. Hermes snorts, and even Iris smiles lightly.

        If there's one thing Olympians love, it's a bit of brashness.

        *if demure < 50
            *set maverickgoddess %+10
            *set olympusinfluence %+5
            *set Morpheus %+10
            "That's right, Princess," Morpheus drawls, his rant forgotten in the wake of your taunt. "I would be more than happy to give you a private tour. Though I must warn you, some of the pieces are rather racy. Prophetic dreams are my duty, but lewd ones…well, let's just say I inspire quite the passion."
            
            "I would sooner gouge my own eyes out," you counter, tossing him a mocking grin. 
            
            His own lips twitch upwards, as if he can sense the wicked curioristy behind your retort.

            Iris clears their throat, snapping your focus away from thoughts of what sensual art featuring Morpheus might look like.
            *goto main17
        *else
            *set underworldinfluence %-10
            *set Morpheus %-10
            Morpheus's reaction surprises you, however. Is that betrayal flashing across his face?

            "I don't see how my interest in art has anything to do with the matter at hand," he says tightly. "A matter we should be taking far more seriously."

            He shoots you a pointed glare when he utters the word [i]we[/i]. You realize he doesn't mean the Council; he means you and him. He means the Underworld.

            Iris clears their throat, yanking your attention away from the hurt in Morpheus's face. 
            *goto main17
    #I don't; letting their little feud play out will be far more enlightening.
        You feign concern, sharing a worried glance with Iris. Then you let your eyes dart between Morpheus and Hermes, as if you're confused.

        Afraid.
        
        *if cunning > 50
            *set underworldinfluence %+5
            *set olympusinfluence %+5
            *set maverickgoddess %+10
            "I know how you Chthonic deities can get carried away when it comes to punishment." Hermes's tone is sharp as a blade. "I'm willing to believe that is what's behind this little outburst and not, say, the Underworld questioning Zeus's judgement."

            Morpheus lifts his chin, holding Hermes's gaze with unflinching resolve. "I wouldn't dare question Zeus's judgement, or lack thereof."

            "Careful, son of Hypnos, Olympus doesn't take well to traitors."

            "Is that why it leaves them to the Underworld?"

            "Enough," Iris interrupts, putting a stop to their exchange.

            You hide your smile. Enlightening indeed. 
            *goto main17
        *else
            *set olympusinfluence %-10
            *set maverickgoddess %-10
            *set respect %-10
            Unfortunately, it seems to make them aware that they're being watched.

            Instead of revealing anything, they merely stare at each other in tense, useless silence.

            Iris clears their throat, drawing everyone's attention to them.
            *goto main17
    #I take control of the situation; both their egos must be kept in check.
        "I delivered many of Odysseus's punishments myself. I can assure you he was far from [i]indulged[/i]," you tell Morpheus, holding his gaze and silently willing him to keep his mouth shut.

        *if leadership > 60
            *set pantheonplayer %+10
            *set respect %+20
            *set Morpheus %+5
            He gives you a begrudging nod. You don't let yourself dwell on the rather shocking fact he did as you bid him.

            Instead, you bestow your most placating smile upon Hermes and add, "You must forgive Morpheus's outburst, us Chthonic deities tend to get carried away when it comes to punishment."

            Hermes snorts, and though there's still an edge to his movements, he has at least resumed them. Beside him, Iris shoots you a grateful glance.
            *goto main17
        *else
            *set pantheonplayer %-10
            *set respect %-20
            *set Morpheus %-5
            He doesn't heed the warning.

            "This might surprise you, Princess, but not everything is about you," he snaps.

            "What [i]is[/i] this truly about then?" Hermes's tone is sharp as a blade. "Go on, son of Hypnos. Enlighten us."

            Morpheus doesn't flinch from the herald's scrutiny. Instead, he lifts his chin, holding his gaze with stubborn resolve. Panic rises inside you as you reach for something to say before he can reply. Before he can make things worse.

            But it is Iris who clears their throat, loud enough to cut through the tension brewing between them.
            *goto main17

*label main17
*page_break

"Let us return to the matters we gathered here to discussed in the first place," the aide offers. They don't wait for a response, instead proceeding to give an update on oaths taken and how they may impact your deliveries.

Hermes nods along, but you doubt he's listening.

"What a thorough summary," he quips when the aide is done. "Thank you. Have you anything to report, Morpheus?"

The dream god crosses his arms before his chest. "Nope."

Hermes's gaze lingers on him, as though trying to determine whether he's lying and, if so, whether he cares.

"Splendid," he settles on before turning to you. "I expect the same can be said for you, ${name}?"

The way he poses it to you is strange, however. Deliberate. It dawns on you then, that he hasn't brought up your performance at all. Neither to praise you for your accomplishments or shame you for your failings.

Perhaps it's an oversight. He is a busy god, after all. Or perhaps there's something else at play. How you bring up Theron's request could offer you an insight into what it may be.

"There is one thing I wish to discuss," you say.

His smile doesn't falter, even if his eyes narrow. "Oh?"

*choice
    #"It concerns Leukas's increased nightmare quota," you add cautiously.
        Iris perks up at that, their gaze turning a curious green.

        You press on. "I understand the people are tired and would benefit from a brief nightmare respite. Not only will it allow them to rest, but I believe it will increase worship in the long run too."
        
        *if diplomacy > 50
            *set pantheonplayer %+15
            *set olympusinfluence %+5
            *set respect %+10
            "It is very noble of you to speak on their behalf," Iris says.

            "And smart," Hermes adds.

            You flash him a grin. "It's all about balance."

            "Indeed," Iris agrees.
            *goto main18
        *else   
            *set pantheonplayer %-10
            *set olympusinfluence %-5
            *set Morpheus %-5
            *set respect %-10
            *set pissedoffhermes true
            "Suck-up," Morpheus grumbles under his breath.

            Hermes's smile widens. Did he hear him? 
            
            Worse, does he agree?
            *goto main18
    *if cautiousrequest = false
        #"The undue suffering of the people of Leukas," you add defiantly.
            You feel Iris and Morpheus frown at you, but you keep your attention on Hermes.

            "Oh." 
        
            This time, it sounds like a warning. But you are not deterred.

            "The demands we have placed on them are far too great. We must scale back on nightmares, let them rest and recover. Not only do they deserve the respite, but it will show them our commitment to balance."
        
            *if dutiful < 50
                *set peoplepleaser %+15
                *set olympusinfluence %+5
                *set respect %+10
                *set Theron %+5
                "A commitment we must do everything in our power to uphold," Iris adds. 

                Hermes glances at his aide, then nods at you. 

                "Indeed," he concedes. "How noble of you to remind us of it."

                You bow, certain Theron will be glad to hear it.
                *goto main18
            *else
                *set olympusinfluence %-15
                *set respect %-10
                *set pissedoffhermes true
                Hermes grips his staff, and for a brief, rather terrifying moment, you fear he might actually hit you with it. 

                "Must we, now? I didn't realize optimizing worship distribution fell under your area of expertise," he says instead.

                "It doesn't," you admit, hating the quiver in your voice.
                
                "Exactly."
                *goto main18
    #"I had an interesting chat with the Lord of Leukas," you add slyly.
        You let the words hang between you. They are, after all, an offering.

        *if cunning > 50
            *set maverickgoddess %+10
            *set respect %+5
            *set pantheonplayer %+5
            He takes it. 

            "Ah, yes. I assume it has to do with his nightmare concerns?" He shakes his head. "What an unfortunate situation."

            "Indeed," you agree. "Perhaps it's worth exerting your influence in Olympus for a less drastic yet still fruitful approach. If we don't do anything about it soon, their worship numbers could dwindle."

            He nods gratefully.
            *goto main18
        *else
            *set maverickgoddess %-10
            *set pantheonplayer %-10
            *set olympusinfluence %-10
            *set respect %-10
            *set pissedoffhermes true
            He doesn't take it.

            "A chat? Isn't that delightful. If only we could all afford such idleness. Alas, some of us have work to do."

            You bite back a sigh. What an unfortunate response. It leaves you with no choice but to go for the kill.

            "Well, he seems to believe his people are being unfairly treated. If we don't do anything about it soon, their worship numbers will dwindle. I worry how that might reflect on the Council."

            And their leader. But you don't say that part aloud.
            *goto main18
    *if cautiousrequest
        #"The whinings of a disgruntled Lord," you add stonily.
            Hermes's smile widens. "I see."

            "Theron of Leukas wishes for his nightmare quota to be reduced. He believes his people are being unfairly punished," you declare.

            "But is it true?" Iris asks, glancing between you and Hermes.

            *if ruthless > 50
                *set olympusinfluence %+15
                *set maverickgoddess %+5
                *set pantheonplayer %+5
                *set respect %+10
                You hold their worried gaze. 

                "If you're asking whether I pulled my punches, you know the answer."

                You never have, and you never will.

                "That is for Zeus to decide," Hermes adds.

                "Of course it is," Morpheus grumbles under his breath.
                *goto main18
            *else
                *set olympusinfluence %-5
                *set pantheonplayer %-10
                *set respect %-5
                You don't reply, but something in their worried gaze makes guilt twist through your chest.

                "Perhaps a less ruthless approach would be wise, then," they finally say, turning to Hermes. "Don't you think?"
                *goto main18

*label main18
*page_break

@{(pissedoffhermes) An awkward, oppressive silence ensues|A brief silence ensues as you all ponder what's next}.

"I shall deliver ${name}'s message to Olympus," @{(pissedoffhermes) Hermes says, and you get the sense he will deliver something else too. Something that won't make you sound too good|Hermes announces}. "You are dismissed."

He begins to fly away, then stops before he reaches the treeline. 

"I almost forgot. No personal deliveries today. Send out your Epiali as per yesterday's instructions."

With that, he's off, propelling across the sky like a shooting star.

"Hear that, Princess?" Morpheus says. "No work tonight. You must be relieved, I know how averse you are to it."

Before you can reply, Iris approaches you. 

"I have a message for you, ${name}."

*page_break

Iris glances at Morpheus, who is too busy sneering at you to have gotten the hint.

"Do you mind?" you snap.

"I do. Last time I checked, Princess, you didn't own this clearing. I can stay here if I please."

"This is from Ares," Iris says, pulling out a small scroll and a carefully wrapped parcel from their satchel.

The smell alone gives the parcel away. Ambrosia cake, sweet and syrupy and somehow still warm.

*fake_choice
    #I beam at Iris, delighted their message is from Ares.
        *set Ares %+5
    *if thoughtof > 1
        #I stare at Iris, unsure about how to feel.
            *set Ares %-5
            It's a nice gesture, of course. But what does he want in return?
    #I glance at Morpheus, distracted by his smirk.
        *set Morpheus %+5
        *set morpheusleft true
        His eyes meet yours, glinting and sharp.
    #I glare at Morpheus, enraged by his smirk.
        *set Morpheus %-5
        *set morpheusleft true
        His eyes meet yours, glinting and sharp.

"Here." Iris presses both the scroll and the cake into your hands, a small smile pulling at their lips. "Enjoy."

They follow after Hermes, carving a beautiful rainbow into the murky sky in their wake.

*page_break

You cast your eyes over Ares's message.

His handwriting is nothing like Hermes's. Neat and surprisingly ornate, it reminds you of the fancy piping that sometimes graces the cakes at Olympian feasts. 

[i]${name},[/i]

[i]I know it is hard for beings such as ourselves to grasp the passage of time. Days melt into years without our notice, decades fly by in a blink. Yet seeing you again has made me painfully aware of how long it has been since we last crossed paths, and how little I wish for time to stretch between us so again.[/i]

[i] @{(thoughtof) Thank you again for visiting me at the Eastern border, and for reminding me of that. The Medians finally|The Medians finally|The Medians finally} retreated, and I am on my way back home.[/i]

[i]It is why I wanted to extend an invitation for you to join me at the oak grove the morning after the new moon. No overbearing parents, no stuffy feasting halls, no political  @{(thoughtof) manouvering. And, more importantly, no stew to mind|manouvering|manouvering}[/i]

[i]Just a long overdue catch-up between old @{(wentwithares) friends. And, Fates willing, three drakon hatchlings|friends}.[/i]

[i]@{(distantares) I understand ambrosia cake is no longer to your tastes, but Zagreus seems quite keen on it. Perhaps you can taunt him with it. It seems you are still very much fond of that|In the meantime, I hope you enjoy the cake. It took all of my admittedly scarce willpower, and Maia's careful ministrations, not to devour the whole batch}.[/i]

[i]Your friend,[/i]

[i]Ares[/i]

You clutch the message to your chest, pondering the whims of the heart within.

*choice
    #Continue to the next chapter.
        *finish Chapter 5
    *if (not(choice_randomtest)) #Restore to the previous checkpoint.
        *restore_checkpoint